Каталог решений - Процедура генерации отдельных элементов формы для даты и времени

В публикации "Раздельный вывод частей даты на форму без программирования" я описал, как без программирования сделать более удобным редактирование времени на форме отдельно от даты. Но всё-равно применение этого способа заставляет разработчика пройтись по всем формам и ручками выполнить указанные действия. Мне самому стало лень, поэтому разработал небольшую процедуру, которая выполняет эти действия. Её можно встроить в общий модуль, например, и вызывать в процедурах переопределения событий формы вроде ПриСозданииФормыНаСервере и других подобных.

Процедура РазделитьЭлементФормыНаДатуВремя(ЭлементФормыДата, Форма) Экспорт

	ИмяЭлемента = ЭлементФормыДата.Имя;
	
	ГруппаДат = Форма.Элементы.Добавить("Группа_" + ИмяЭлемента + "_ДатаВремя", Тип("ГруппаФормы"), ЭлементФормыДата.Родитель);
	ГруппаДат.Вид = ВидГруппыФормы.ОбычнаяГруппа;
	ГруппаДат.ОтображатьЗаголовок = Ложь;
	ГруппаДат.Группировка = ГруппировкаПодчиненныхЭлементовФормы.ГоризонтальнаяВсегда;
	
	ЭлементФормыДата.Формат = "ДФ='dd.MM.yyyy'";
	ЭлементФормыДата.ФорматРедактирования = ЭлементФормыДата.Формат;   
	Форма.Элементы.Переместить(ЭлементФормыДата, ГруппаДат);
	
	ЭлементВремя = Форма.Элементы.Добавить(ИмяЭлемента + "_Время", Тип("ПолеФормы"), ГруппаДат);
	ЭлементВремя.ПутьКДанным = ЭлементФормыДата.ПутьКДанным;
	ЭлементВремя.Вид = ВидПоляФормы.ПолеВвода;
	ЭлементВремя.Формат = "ДФ='HH:mm'";
	ЭлементВремя.ФорматРедактирования = ЭлементВремя.Формат;
	ЭлементВремя.ПоложениеЗаголовка = ПоложениеЗаголовкаЭлементаФормы.Нет;
	ЭлементВремя.КнопкаРегулирования = Истина;
	ЭлементВремя.КнопкаВыбора = Ложь;

КонецПроцедуры

Разберём код:

• Процедура получает в параметрах элемент формы реквизита типа "Дата" и саму форму;
• Создается внутри родителя текущего элемента горизонтальная скрытая группа для отображения даты и времени рядом;
• У исходного элемента устанавливается формат без времени, он переносится в новую группу;
• Создается элемент с таким же путём к данным, заголовок убирается, формат устанавливается для отображения только часов и минут, кнопка выбора (календарь) скрывается, а кнопка регулирования — включается.

Во время разработки процедуры столкнулся с интересными особенностями программной работы с элементами формы, которыми хочу поделиться:

• Далеко не все свойства элементов формы, особенно при программном создании, отображаются в подсказках выпадающего списка — например, не показывается "Формат", "КнопкаРегулирования", "КнопкаВыбора", "Группировка" (для группы);
• Первый раз использовал метод Переместить коллекции элементов формы — он используется для изменения родителя ранее созданного элемента формы, так как само свойство Родитель доступно только для чтения.