Переделка модального окна в режиме выбора в немодальное или ошибка dZO.showModalDialog

1C хоть и продолжает яростную борьбу с модальными окнами (http://v8.1c.ru/o7/201301nm), но все еще попадаются места, где нужно переделать модальный вызов окон в немодальный.
Для этой цели уже достаточно давно, с платформы 8.3.5.1068 появился инструмент рефакторинг http://v8.1c.ru/o7/201312ref/index.htm.
Использовать нужно именно его и новые методы вроде ПоказатьВводЗначения(), однако не везде установлена 8.3, а работу приложения в web-интерфейсе "вынь да положь".
Предлагаю простой вариант переделки модального окна в режиме выбора в немодальное, который будет работать и на 8.2 и на 8.3.

Категория: Публикации 1С

Подробнее

Описание
Подробнее

Описание

В качестве примера возьмем обработку ШаблоныЭтикетокИЦенников из УТ11.0 (в 11.1 такая же, без видимых изменений).

В Web-интерфейсе при попытке заполнить строки шаблонами этикеток у меня в хроме вылетела такая ошибка (к слову в IE все отработало нормально, но не суть, завтра может и не отработать):

Переделываем следующим образом:

Было (1 процедура):

&НаКлиенте
Процедура УстановитьШаблонЭтикеток(Команда)
	
	МассивСтрок = Элементы.Товары.ВыделенныеСтроки;
	
	ПараметрыФормыВыбора = Новый Структура;
	ПараметрыФормыВыбора.Вставить("Отбор", Новый Структура("Назначение", ПредопределенноеЗначение("Перечисление.НазначенияШаблоновЭтикетокИЦенников.Товары")));
	
	ВыбранноеЗначение = ОткрытьФормуМодально("Справочник.ШаблоныЭтикетокИЦенников.ФормаВыбора", ПараметрыФормыВыбора, ЭтаФорма);	
	
	Если ЗначениеЗаполнено(ВыбранноеЗначение) Тогда
		
		Для Каждого НомерСтроки Из МассивСтрок Цикл
			СтрокаТЧ = Объект.Товары.НайтиПоИдентификатору(НомерСтроки);
			СтрокаТЧ.ШаблонЭтикетки = ВыбранноеЗначение;
		КонецЦикла;
		
	КонецЕсли;
	
КонецПроцедуры

Стало (3 процедуры):

&НаКлиенте
Процедура УстановитьШаблонЭтикеток(Команда)
	
	ПараметрыФормыВыбора = Новый Структура;
	ПараметрыФормыВыбора.Вставить("Отбор", Новый Структура("Назначение", ПредопределенноеЗначение("Перечисление.НазначенияШаблоновЭтикетокИЦенников.Товары")));
	ПараметрыФормыВыбора.Вставить("ЗакрыватьПриВыборе", Истина);	
	
	ОткрытьФорму("Справочник.ШаблоныЭтикетокИЦенников.ФормаВыбора", ПараметрыФормыВыбора, ЭтаФорма, ЭтаФорма.УникальныйИдентификатор);	
	
КонецПроцедуры

&НаКлиенте
Процедура ОбработкаВыбора(ВыбранноеЗначение, ИсточникВыбора)
	
	Если ИсточникВыбора.ИмяФормы = "Справочник.ШаблоныЭтикетокИЦенников.ФормаВыбора" Тогда
		ЗаполнитьШаблоныЭтикетокИЦенниковВСтроках(ВыбранноеЗначение);
	КонецЕсли; 
	
КонецПроцедуры

&НаКлиенте
Процедура ЗаполнитьШаблоныЭтикетокИЦенниковВСтроках(СсылкаШаблон)

	МассивСтрок = Элементы.Товары.ВыделенныеСтроки;

	Если ЗначениеЗаполнено(СсылкаШаблон) Тогда
		
		Для Каждого НомерСтроки Из МассивСтрок Цикл
			
			СтрокаТЧ = Объект.Товары.НайтиПоИдентификатору(НомерСтроки);
			
			Если ЦенникИлиЭтикетка Тогда
				СтрокаТЧ.ШаблонЦенника = СсылкаШаблон;
			Иначе	
				СтрокаТЧ.ШаблонЭтикетки = СсылкаШаблон;
			КонецЕсли;			
			
		КонецЦикла;
		
	КонецЕсли;

КонецПроцедуры

Вкратце поясню:

Функцию ОткрытьФормуМодально() мы заменили на ОткрытьФорму() с параметром ЗакрыватьПриВыборе = Истина.

Теперь вопрос: как же получить выбранное значение и обработать его? Оказывается очень просто — формы для выбора, при своем закрытии, автоматом рассылают оповещение о выборе формам владельцам (тем, которые указаны в 3-м параметре метода ОткрытьФорму()). Причем, оповещают и формы для выбора по-умолчанию, и формы, сделанные вручную. Нам остается только принять нужное оповещение в методе ОбработкаВыборка.

Также смотрите схожие публикации:

//sale.itcity.ru/public/236382/

//sale.itcity.ru/public/305935/

Каталог решений - Переделка модального окна в режиме выбора в немодальное или ошибка dZO.showModalDialog