Каталог решений - Сохранение реквизитов и табличных частей объектов в XML

Представленные в публикации процедуры были рождены потребностью сохранять настройки внешних обработок с возможностью последующего их использования на других компьютерах и в других информационных базах. Работают они, однако, не только для обработок, но и для любых других объектов 1С, имеющих реквизиты и табличные части. Сам я пользуюсь ими достаточно часто, при решении самых различных задач, потому решил поделиться, глядишь кому-нибудь пригодится. Так же, думаю, этот материал может быть полезен начинающим программистам как пример рекурсивного чтения структуры XML-файла, к тому же процедуры малы, просты и легко «допиливаются» под специфические задачи.

Сохранение производится процедурой СохранитьРеквизитыИТабличныеЧасти. В качестве параметров она принимает сохраняемый объект и имя файла. Ссылочные реквизиты сохраняются в виде GUID.

Процедура СохранитьРеквизитыИТабличныеЧасти (Объект, ИмяФайлаXML=Неопределено) Экспорт
    ФайлXML = Новый ЗаписьXML;
    ФайлXML.ОткрытьФайл(ИмяФайлаXML);
    ФайлXML.ЗаписатьОбъявлениеXML();
    ФайлXML.ЗаписатьНачалоЭлемента(«Root»);
    ФайлXML.ЗаписатьАтрибут(«Объект»,Объект.Метаданные().Имя);
//Сохраняем реквизиты
    Для Каждого Реквизит Из Объект.Метаданные().Реквизиты Цикл
        ФайлXML.ЗаписатьНачалоЭлемента(«Реквизит»);
        ФайлXML.ЗаписатьАтрибут(«Имя», Реквизит.Имя);
        ТипЗначения = ТипЗнч(Объект[Реквизит.Имя]);
        Если Не ТипЗначения = Тип(«Неопределено») Тогда
            ФайлXML.ЗаписатьАтрибут(«ИмяТипа», XMLТип(ТипЗначения).ИмяТипа);
            ФайлXML.ЗаписатьАтрибут(«URI», XMLТип(ТипЗначения).URIПространстваИмен);
        КонецЕсли;
        ФайлXML.ЗаписатьТекст(XMLСтрока(Объект[Реквизит.Имя]));
        ФайлXML.ЗаписатьКонецЭлемента();
    КонецЦикла;
//Сохраняем табличные части
    Для Каждого ТЧ из Объект.Метаданные().ТабличныеЧасти Цикл
        ФайлXML.ЗаписатьНачалоЭлемента(«ТабличнаяЧасть»);
        ФайлXML.ЗаписатьАтрибут(«Имя», ТЧ.Имя);
        Для Каждого СтрокаТЧ из Объект[ТЧ.Имя] Цикл
            ФайлXML.ЗаписатьНачалоЭлемента(«ЭлементКоллекции»);
            Для Каждого РеквизитТЧ Из ТЧ.Реквизиты Цикл
                ФайлXML.ЗаписатьНачалоЭлемента(«Реквизит»);
                ФайлXML.ЗаписатьАтрибут(«Имя», РеквизитТЧ.Имя);
                ТипЗначения = ТипЗнч(СтрокаТЧ[РеквизитТЧ.Имя]);
                Если Не ТипЗначения = Тип(«Неопределено») Тогда
                    ФайлXML.ЗаписатьАтрибут(«ИмяТипа», XMLТип(ТипЗначения).ИмяТипа);
                    ФайлXML.ЗаписатьАтрибут(«URI», XMLТип(ТипЗначения).URIПространстваИмен);
                КонецЕсли;
                ФайлXML.ЗаписатьТекст(XMLСтрока(СтрокаТЧ[РеквизитТЧ.Имя]));
                ФайлXML.ЗаписатьКонецЭлемента();
            КонецЦикла;
            ФайлXML.ЗаписатьКонецЭлемента();
        КонецЦикла;
        ФайлXML.ЗаписатьКонецЭлемента();
    КонецЦикла;
    Если Не ФайлXML=Null Тогда
        ФайлXML.ЗаписатьКонецЭлемента();
        ФайлXML.Закрыть();
    КонецЕсли;
КонецПроцедуры

За чтение объекта отвечают процедуры ЗагрузитьРеквизитыИТабличныеЧасти и ЗагрузитьОбъектРекурсивно. Чтобы прочитать объект вызывается первая, ей передаются объект, который необходимо заполнить, и имя файла. Вторая является вспомогательной.

Процедура ЗагрузитьРеквизитыИТабличныеЧасти(Объект, ИмяФайлаXML=Неопределено) Экспорт
    Если Не ИмяФайлаXML = Неопределено Тогда
        ФайлXML = Новый ЧтениеXML;
        ФайлXML.ОткрытьФайл(ИмяФайлаXML);
        Пока ФайлXML.Прочитать() Цикл
            Если ФайлXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
                ЗагрузитьОбъектРекурсивно(ФайлXML, Объект, ФайлXML.Имя);
            КонецЕсли
        КонецЦикла;
    КонецЕсли;
КонецПроцедуры

Процедура ЗагрузитьОбъектРекурсивно(ФайлXML, Объект, знач ИмяУзла)
    ИмяТипа = «»;
    ПространствоИмен = «»;
    Пока ФайлXML.ПрочитатьАтрибут() Цикл
        Если ФайлXML.Имя = «ИмяТипа» Тогда
            ИмяТипа = ФайлXML.Значение;
        ИначеЕсли ФайлXML.Имя = «URI» Тогда
            ПространствоИмен = ФайлXML.Значение;
        КонецЕсли;
    КонецЦикла;
    Пока ФайлXML.Прочитать() Цикл
        Если ФайлXML.ТипУзла = ТипУзлаXML.КонецЭлемента И ФайлXML.Имя = ИмяУзла Тогда
            Возврат;
        ИначеЕсли ФайлXML.ТипУзла = ТипУзлаXML.Текст Тогда
            ТипОбъекта = ИзXMLТипа(ИмяТипа, ПространствоИмен);
            Если НЕ ТипОбъекта = Неопределено тогда
                Объект = XMLЗначение(ТипОбъекта, ФайлXML.Значение);
            КонецЕсли;
        ИначеЕсли ФайлXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
            ИмяТекУзла = ФайлXML.Имя;
            Если ФайлXML.Имя = «ЭлементКоллекции» Тогда
                ЗагрузитьОбъектРекурсивно(ФайлXML, Объект.Добавить(), ИмяТекУзла);
            Иначе
                Если ФайлXML.ПрочитатьАтрибут() Тогда
                    ЗагрузитьОбъектРекурсивно(ФайлXML, Объект[ФайлXML.Значение], ИмяТекУзла);
                КонецЕсли;
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры

В приложенном файле демонстрационная обработка, позволяющая сохранить ссылочный объект БД в файл и заполнить объект из файла. Заполняемый объект должен быть того же типа, что и сохраненный, а также он должен быть предварительно создан, сохранен в ИБ и выбран в поле «Ссылка».