Каталог решений - Статистика для кадровика

В ходе работы выяснилось, что у сотрудника отдела кадров по ролям есть доступ к отчетности по статистике но т.к. как ему не доступен раздел 1с-Отчетность пришлось добавить внешнюю форму с кнопкой нужных ему форм.

Пример кода в форме обработки

  &НаКлиенте
  Процедура КомандаОткрытьП4(Команда)
      ПараметрыОткрытия = Новый Структура();
      ПараметрыОткрытия.Вставить("Раздел", ПредопределенноеЗначение("Перечисление.СтраницыЖурналаОтчетность.Отчеты"));
      //МассивВидовОтчетов.Добавить("Статистика: Форма П-4 (НЗ)");
      ПараметрыОткрытия.Вставить("ВидОтчетаКадровика","Статистика: Форма П-4");
      ОткрытьФорму("ОбщаяФорма.РегламентированнаяОтчетность", ПараметрыОткрытия);
      
      Оповестить("Открытие формы 1С-Отчетность", ПараметрыОткрытия);
  КонецПроцедуры

Данная обработка была добавлена как внешняя обработка

  Функция СведенияОВнешнейОбработке() Экспорт
      
      
      МассивНазначений = Новый Массив;
      МассивНазначений.Добавить("Подсистема.Кадры");
      
      ПараметрыРегистрации = Новый Структура;
      ПараметрыРегистрации.Вставить("Вид",                   "ДополнительнаяОбработка");
      ПараметрыРегистрации.Вставить("Назначение",            МассивНазначений);
      ПараметрыРегистрации.Вставить("Наименование",          "Работа с отчетностью (Статистика)");
      ПараметрыРегистрации.Вставить("Версия",                Версия());
      ПараметрыРегистрации.Вставить("БезопасныйРежим",       Истина);
      ПараметрыРегистрации.Вставить("Информация",            "");
      ПараметрыРегистрации.Вставить("ВерсияБСП",             СтандартныеПодсистемыСервер.ВерсияБиблиотеки());
      ТаблицаКоманд = ПолучитьТаблицуКоманд();
      
  
      ДобавитьКоманду(ТаблицаКоманд,
      "Работа с отчетностью (Статистика)",
      "РаботаСОтчетностьюСтатистика",
      "ОткрытиеФормы");
  
      ПараметрыРегистрации.Вставить("Команды", ТаблицаКоманд);
      
      Возврат ПараметрыРегистрации;
      
  КонецФункции

И добавить в расширение  для общую форму

"ОбщаяФорма.РегламентированнаяОтчетность",

где было прописано выполнение кода при создании на сервере

   &НаСервере
  Процедура Мое_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
      
      Если Параметры.Свойство("ВидОтчетаКадровика") Тогда
          МассивВидовОтчетов = Новый Массив;
          МассивВидовОтчетов.Добавить(Параметры.ВидОтчетаКадровика);
          Элементы.ОтборВидОтчета.СписокВыбора.ЗагрузитьЗначения(МассивВидовОтчетов);
          ВидОтчета = Параметры.ВидОтчетаКадровика;
          ДействияПриИзмененииОтборов(ЭтаФорма);
          Элементы.ОтборВидОтчета.Доступность      = Ложь;
          Элементы.ГруппаСсылокРазделы.Доступность = Ложь;
          Элементы.ГруппаСсылокРазделы.Видимость   = Ложь;
      КонецЕсли;
      
  КонецПроцедуры

После используя стандартный механизм был добавлен пункт запуска внешней обработки  (кадры-дополнительные обработки). 

Данное решение было проверено на Зарплата и управление персоналом КОРП, редакция 3.1 (3.1.14.436).